Built it in linux, builds win executable and clicking confirmations crashes it in MonoDev.

[KoboDev]

Launching it in MonoDev on linux, built correctly (with 2 warnings) nothing seemed wrong. It built a windows executable, not entirely the best thing but if it works it works. But not even an attempt to open the confirmations window, it straight crashes. (no report)

Using Wine to launch it outside of Mono puts a big ol' crash in my face.

Got any tips? Any way to make it workable in Wine or maybe even an .sh executable?

[noabody]

I'm on Manjaro Linux with is Arch-like and uses something called PKGBUILD. I can't say that I have actually tested this out on my account but perhaps the build layout could be useful. I build from command line:

# Maintainer: Noa Body <[email protected]>

pkgname=sda
_pkgname='Steam Desktop Authenticator'
pkgver=1.0.10.r298.8a408f1
pkgrel=1
pkgdesc="$_pkgname."
arch=(any)
url=https://github.com/Jessecar96/SteamDesktopAuthenticator
license=(MIT)
depends=(hicolor-icon-theme mono mono-addins)
makedepends=(gendesk git imagemagick inkscape mono-msbuild 'mono-nightly>=6.13.0.1176' nuget)
provides=("$pkgname")
conflicts=("$pkgname")
replaces=("$pkgname")
source=("$pkgname"::git+https://github.com/Jessecar96/SteamDesktopAuthenticator.git
        "$pkgname".sh)
sha256sums=('SKIP'
            '092c575f2069dd95a3951593a2c4e850a0b513ef3f2338fae482a198210cd423')

pkgver() {
  cd "$pkgname"
  local _ver="$(grep -Pio "evers.*\b.*\d+\.[[:alnum:]\.]+" "$_pkgname"/Properties/AssemblyInfo.cs | grep -Pio '\d+\.[[:alnum:]\.]+')"
  printf "%s.r%s.%s" "$_ver" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  gendesk -f -n --name='Steam Authenticator' --comment="$_pkgname" --custom='Keywords=game;console;' --exec="$pkgname %f" --icon="$pkgname" --terminal=false --categories='GNOME;GTK;Utility' --startupnotify=false --pkgname="$pkgname"
  if [ ! -f "$pkgname.svg" ]; then
    convert -thumbnail 256x256 "$pkgname"/icon.png "$pkgname".png
    inkscape "$pkgname".png --export-plain-svg --export-filename="$pkgname".svg
    rm "$pkgname".png
  fi
  cd "$pkgname"
  git submodule update --init --recursive
  nuget restore "$_pkgname/$_pkgname".sln
  nuget restore lib/SteamAuth/SteamAuth/SteamAuth.sln
  msbuild "$_pkgname/$_pkgname".sln /p:Configuration="Release"\;Platform="x86" /t:Clean
}

build() {
  cd "$pkgname"
  msbuild "$_pkgname/$_pkgname".sln /p:Configuration="Release"\;Platform="x86" /t:Build
}

package() {
  install -dm 755 "$pkgdir"/usr/{bin,lib/"$pkgname",share/{applications,icons/hicolor/scalable/apps}}
  install -m 755 "$pkgname".sh "$pkgdir"/usr/bin/"$pkgname"
  install -m 644 "$pkgname".desktop "$pkgdir"/usr/share/applications/
  install -m 644 "$pkgname".svg "$pkgdir"/usr/share/icons/hicolor/scalable/apps/
  install -m 644 "$pkgname/$_pkgname"/bin/Release/Steam*.exe "$pkgdir"/usr/lib/"$pkgname"/SteamAuth.exe
  install -m 644 "$pkgname/$_pkgname"/bin/Release/{Cef,chrome,Command,d3d,lib,Newton,Steam}*.dll "$pkgdir"/usr/lib/"$pkgname"/
  install -m 644 "$pkgname/$_pkgname"/bin/Release/*.{bin,dat} "$pkgdir"/usr/lib/"$pkgname"/
  install -m 644 "$pkgname/$_pkgname"/bin/Release/{cef,*percent}.pak "$pkgdir"/usr/lib/"$pkgname"/
  install -m 644 "$pkgname/$_pkgname"/bin/Release/Cef*.exe "$pkgdir"/usr/lib/"$pkgname"/
}